suche Rezz Script

[Bogus Curry]

Hallölle ;D

Hab ein Script in meinen Iventar gefunden ;D

Code:

// This script is licensed under GPL license version 2
//
// In short: feel free to redistribute and modify it, as long as
// any copies of it can be redistributed and modified as well.
//
// The official text of the licence is available at
// http://www.gnu.org/licences/gpl.html
//
// (c) The owner of Avatar Catherine Pfeffer, 2010

string VERSION = "0.1.1";
integer DIALOG = -121;
integer CHANNEL = -122;
integer MAGIC = 42;

rezzer()
{
    integer n = llGetInventoryNumber(INVENTORY_OBJECT);
    integer i;

    vector pos = llGetPos();
    rotation rot = llGetRot();
        
    for (i = 0; i < n; i++)
    {
        string name = llGetInventoryName(INVENTORY_OBJECT, i);
        llRezAtRoot(name, pos, ZERO_VECTOR, rot, MAGIC);
    }
}

default
{
    state_entry()
    {
        llSetTouchText("Menu");
        llListen(DIALOG, "", llGetOwner(), "");
        llOwnerSay("Open Source Faux Build version " + VERSION + ".\n" +
                   "Click on the Faux Build cube to get the menu.");
    }
    
    on_rez(integer number)
    {
        llResetScript();
    }

    touch_start(integer num)
    {
        integer i;
        
        for (i = 0; i < num; i++)
        {
            if (llDetectedKey(i) != llGetOwner())
            {
                llSay(0, "You are not my owner.");
            }
            else
            {
                llDialog(llGetOwner(), "Choose action to perform",
                         [ "Unrez", "Reposition", "Freeze", "Prepare", "Rez" ], DIALOG);
            }
        }
    }

    listen(integer channel, string name, key id, string message)
    {
        if (message == "Prepare")
        {
            vector pos = llGetPos();
            rotation rot = llGetRot();
            
            llShout(CHANNEL, "Position;" + (string) pos + ";" + (string) rot );
        }
        else if (message == "Rez")
        {
            rezzer();
        }
        else if (message == "Unrez")
        {
            llShout(CHANNEL, "Suicide");
        }
        else if (message == "Reposition")
        {
            vector pos = llGetPos();
            rotation rot = llGetRot();
            
            llShout(CHANNEL, "Moveto;" + (string) pos + ";" + (string) rot );
        }
        else if (message == "Freeze")
        {
            llShout(CHANNEL, "Cleanup");
        }
        else llOwnerSay("Unknown command");
    }
}

habs nicht getestet ...

Hier die Anleitung ;D

Open Source Faux Build - tested in OpenSim.


Saving your build
===========

Put the Faux Build cube next to your build.
Drag the script "Faux Build - objects script" into all the objects (at the root prim). Give relevant names to them.
Click on the Faux Build cube. A blue menu appears. Select "Prepare".
Take into your inventory a copy of all the objects that have answered that they were ready.
Drag them from your inventory into the contents of the Faux Build cube.
Write down the coordinates and rotation of the Faux Build cube if you want to be able to recreate the build exactly at the same place.
Take a copy of theFaux Build cube in your inventory. Rename it to reflect its contents if you wish.


Restoring your build
============

Place the Faux Build cube where you want to rez again the build. Orient it in the new direction of the build.
Click on the Faux Build cube. A blue menu appears. Select "Rez".
If the result is not satisfying, click again on the cube and select "Unrez".
You can also move and rotate the Faux Build cube and click "Reposition".
When you're satisfied with the result, click "Freeze".


Important notice
==========

The descriptions of the objects stored in the Faux Build cube will be lost.
Do not use with "no copy" or "no modify" objects.
The author denies any responsability in case of loss of data, of virtual goods, or of working hours.
Send feedback to Catherine Pfeffer, on Second Life or on New World Grid.