Eure Outfits

[Leora Jacobus]

Und nach endlosem Gepfriemele ist der erste Mann fertig!


MichaelMAM01_Vendor700x350 by Leora Jacobus, auf Flickr

- alleine der Gürtel mit dem Wams hat 40 Prims! Er ist nämlich allein mit 28 "Perlen" verziert. Jedes davon muß als Skulptie erstellt und millimetergenau in Position gebracht werden! - und auch dem Mann selber zu gestalten war nicht so ohne! Gute Männerskins sind rar! Ich weiß er hat das übliche Dreckrändchen am Hals! Aber DAS Problem ist in SL wie in OS bekannt! unbd ich werd's einfach ignorieren! ... ebenso wie die Augenwinkel- Entzündung!

Meine Mutter pflegte zu sagen: "So genau is too genau!"

[Mareta Dagostino]

Wow, Mann oh Mann!

[Leora Jacobus]

Irgendwie macht das süchtig!! Ich vergesse dabei zu essen und zu schlafen! Habe selbst nie Schiffsmodelle aus diesen 1000- Teile- Bausätzen gebastelt, aber andere dabei beobachtet. Das muß ähnlich sein. Tausend winzige Teile zusammenzupuzzeln und zu beobachten wie dabei etwas großes und schönes entsteht.

Alleine schon so eine Sculptmap hochzuladen (buntschillernde Textur) und dann wird plötzlich ein merkwürdig geformter Prim daraus. Der braucht dann "nur" noch 1.) für Größe x y z Werte, 2.) für Rotationswinkel x y z Werte 3.) für Position im Raum x y z Werte und zwar vier Stellen nach dem Komma genau und natürlich noch eine Textur, die richtige und von der noch so 4-5 Werte ... dann isser perfekt!

Gottseidank waren wenigstens die 28 "Perlen" - so eher kleine Pfeilspitzen - die gleichen Sculpts. Da brauchst Du dann von jeder "nur" noch die Rotation und die Position im Raum. Dabei hilft der uralte Loop Rezzer Script von 2006 den ich wieder ausgegraben habe und den man zum Errstellen von Flexiröcken oder Perlenketten benutzen kann.

[Leora Jacobus]

Falls den Looprezzer einer brauchen - und noch nicht haben - sollte:

Einen Würfel rezzen - da rein das Script packen und ein "Object" das ihr vervielfältigt und in einer Ellipse aufgereiht haben möchtet. Dies "Object" sollte bei Winkeln noch 0-0-0 haben. In meinem Falle ware das sowas wie eine Pfeilspitze Dann auf den Würferl klicken und 1 Minute warten: fertig ist der LOOP - Der Script so wie ich ihn benutzt habe lautet:

Code:

////////////////////////////////////////////////////////////////////////////////
// LoopRez v0.6, by Ged Larsen, 20 December 2006
//
// - rez a number of objects in an ellipse, whose size is determined by xRadius and yRadius
// - all facing "outwards", along a tangent to the ellipse
// - can set how much the objects flare outwards
// - properly handles object rotation corrections (for example, X-axis 180 degree rotation helps for flexi-prim skirts)
// - can also get a 'saddle' bend, to generate a bend that might help for necklaces (from Ariane Brodie)
//
// To use:
// 1) create a prim that will contain this script and the object to use
// 2) put the script into the prim
// 3) create an object that will be used, and name it "Object"
// 4) put "Object" into the prim containing the script, by dragging it from your inventory
// 5) get out of Edit Mode, and touch the prim
//
// Random note:
// - this version does NOT insure equal spacing of objects along the perimeter of the ellipse
// - i.e., objects "bunch up" at the long ends of an ellipse; the effect should be acceptable for non-extreme ellipses
// - even spacing of objects can be accomplished, but requires simulation of integral calculus, which slows down the script
//
// References:
// - tangent formulas from: http://mathworld.wolfram.com/Ellipse.html


////////////////////////////////////////////////////////////////////////////////
// CONFIGURATION PARAMETERS, change these to your liking

string objectName = "Object"; // object to use; will need to be in the inventory of the prim containing this script
integer numObjects = 34; // how many objects
float xRadius = 0.2; // ellipse x-axis radius in meters
float yRadius = 0.25; // ellipse y-axis radius in meters
float flareAngle = 0.0; // how many DEGREES the bottom of object will flare outwards, the "poof" factor
float bendCoefficient = 0.0; // makes a "saddle shape", bends DOWN this number of meters at extremes of X-axis
vector rotOffset = <0.0, 0.0, 270.0>; // rotation offset in DEGREES -- fixes the rotation of ALL objects; for flexi prims, often you will want <180.0,>
vector posOffset = <0.0, 0.0, 2.0>; // position offset



////////////////////////////////////////////////////////////////////////////////
// No need to mess with anything below here

makeLoop()
{
integer n; // which object is being placed
float theta; // angle in radians
vector pos; // position
rotation rot; // rotation in quaternion format

for(n = 0; n < numObjects; n++) {

theta = TWO_PI * ( (float)n / (float)numObjects );

pos.x = xRadius * llCos(theta); // ellipse: 2x xRadius meters wide
pos.y = yRadius * llSin(theta); // ellipse: 2x yRadius meters wide
pos.z = -bendCoefficient*llCos(theta)*llCos(theta); // saddle shape, bending downwards on X-axis
pos = pos + llGetPos() + posOffset;

rot = llEuler2Rot(<rotOffset.x*DEG_TO_RAD, rotOffset.y*DEG_TO_RAD, rotOffset.z*DEG_TO_RAD>); // user-chosen rotation offset correction
rot = rot * llEuler2Rot(<0, -1*flareAngle*DEG_TO_RAD, 0>); // flare generation (poof)

// the following make the objects face outwards properly for an ellipse; using theta alone is only correct for a circle
// the scary formula calculates a unit vector TANGENTIAL to the ellipse, and llRotBetween is used to figure out how much the object needs to rotate to lie parallel to the tangent
rot = rot * llRotBetween(<0.0,1.0,0.0>, <-1.0 * xRadius * llSin(theta) / ( llSqrt ( (yRadius*yRadius * llCos(theta) * llCos(theta)) + (xRadius*xRadius * llSin(theta) * llSin(theta))) ),yRadius * llCos(theta) / ( llSqrt ( (yRadius*yRadius * llCos(theta) * llCos(theta)) + (xRadius*xRadius * llSin(theta) * llSin(theta))) ),0.0>);
if ( n== (numObjects/2) ) // LSL's implementation of llRotBetween at theta = pi radians is reversed at 180 degrees, so this manually corrects it
rot = rot * llEuler2Rot( <0,PI,0> );

llRezObject(objectName, pos, ZERO_VECTOR, rot, 0);
}
}

default
{
touch_start(integer total_number)
{
if (llDetectedOwner(0) == llGetOwner())
{
makeLoop();
}
}
}

Ihr könnt noch den kleineren und größeren Durchmesser der Ellipse wählen, die Anzahl der Objects und die Winkel x y z in der das Object gedreht werden soll. Beim ersten Versuch hatte ich da alles Nullen, da flogen die kleinen "Pfeile" hintereinander her. Dann habe ich 0 0 270 gewählt also "vector rotOffset = <0.0, 0.0, 270.0>" da zeigten sie nach außen.

Das Ergebnis müsst ihr noch verlinken. Am besten in die Mitte (direkt über die LooprRezzBox) eine Kugel setzen und die als Rootprim zuletzt verlinken. Das fertige Produkt habe ich dann dicht unter den zu verzierenden Gürtelteil plaziert und wieder entlinkt. Dann kann die Feiinjustierung losgehen. SO sah das aus:


LoopRezz by Leora Jacobus, auf Flickr